;
; Исходный код среды исполнения ПВТ-ОО.
;
; Этот исходный код является частью проекта ПВТ-ОО.
;
; Copyright © 2021 Малик Разработчик
;
; Это свободная программа: вы можете перераспространять её и/или
; изменять её на условиях Меньшей Стандартной общественной лицензии GNU в том виде,
; в каком она была опубликована Фондом свободного программного обеспечения;
; либо версии 3 лицензии, либо (по вашему выбору) любой более поздней версии.
;
; Эта программа распространяется в надежде, что она может быть полезна,
; но БЕЗО ВСЯКИХ ГАРАНТИЙ; даже без неявной гарантии ТОВАРНОГО ВИДА
; или ПРИГОДНОСТИ ДЛЯ ОПРЕДЕЛЁННЫХ ЦЕЛЕЙ. Подробнее см. в Меньшей Стандартной
; общественной лицензии GNU.
;
; Вы должны были получить копию Меньшей Стандартной общественной лицензии GNU
; вместе с этой программой. Если это не так, см.
; <http://www.gnu.org/licenses/>.
;
; <fold push/pop/peek>
if(used inst$l4push) ; <fold >
inst l4push ; (value in ymm0)
push2
vmovdqu yword[rsp], ymm0
set TAG_LONG4
end_inst
end if ; </fold>
if(used inst$l4pop) ; <fold >
inst l4pop ; (): value in ymm0
overify TAG_LONG4
vmovdqu ymm0, [rsp]
pop2set
end_inst
end if ; </fold>
; </fold>
; <fold conversion>
if(used inst$l4tob4) ; <fold >
inst l4tob4
overify TAG_LONG4
vmovdqu ymm0, [rsp]
vpand ymm0, ymm0, [l8.03]
vshufps ymm0, ymm0, ymm0, $d8
vextracti128 xmm1, ymm0, $01
vpslldq xmm1, xmm1, $08
vpor xmm0, xmm0, xmm1
vpxor xmm1, xmm0, xmm0
vpackusdw xmm0, xmm0, xmm1
vpackuswb xmm0, xmm0, xmm1
vmovdqa xword[rsp+$10], xmm0
pop1set TAG_BYTE4
end_inst
end if ; </fold>
if(used inst$l4tos4) ; <fold >
inst l4tos4
overify TAG_LONG4
vmovdqu ymm0, [rsp]
vpand ymm0, ymm0, [l8.03]
vshufps ymm0, ymm0, ymm0, $d8
vextracti128 xmm1, ymm0, $01
vpslldq xmm1, xmm1, $08
vpor xmm0, xmm0, xmm1
vpxor xmm1, xmm0, xmm0
vpackusdw xmm0, xmm0, xmm1
vmovdqa xword[rsp+$10], xmm0
pop1set TAG_SHORT4
end_inst
end if ; </fold>
if(used inst$l4toi4) ; <fold >
inst l4toi4
overify TAG_LONG4
vmovdqu ymm0, [rsp]
vpand ymm0, ymm0, [l8.03]
vshufps ymm0, ymm0, ymm0, $d8
vextracti128 xmm1, ymm0, $01
vpslldq xmm1, xmm1, $08
vpor xmm0, xmm0, xmm1
vmovdqa xword[rsp+$10], xmm0
pop1set TAG_INT4
end_inst
end if ; </fold>
if(used inst$l4tol) ; <fold >
inst l4tol
overify TAG_LONG4
vmovq xmm0, [rsp]
vmovdqa xword[rsp+$10], xmm0
pop1set TAG_LONG
end_inst
end if ; </fold>
if(used inst$l4tol2) ; <fold >
inst l4tol2
overify TAG_LONG4
vmovdqa xmm0, [rsp]
vmovdqa xword[rsp+$10], xmm0
pop1set TAG_LONG2
end_inst
end if ; </fold>
if(used inst$l4tol8) ; <fold >
inst l4tol8
overify TAG_LONG4
push2
vmovdqu ymm0, [rsp+$20]
vmovdqu64 zword[rsp], zmm0
set TAG_LONG8
end_inst
end if ; </fold>
if(used inst$l4tof4) ; <fold >
inst l4tof4
overify TAG_LONG4
vmovdqu ymm0, [rsp]
vcvtqq2ps xmm0, ymm0
vmovdqa xword[rsp+$10], xmm0
pop1set TAG_FLOAT4
end_inst
end if ; </fold>
if(used inst$l4tod4) ; <fold >
inst l4tod4
overify TAG_LONG4
vmovdqu ymm0, [rsp]
vcvtqq2pd ymm0, ymm0
vmovdqu yword[rsp], ymm0
set TAG_DOUBLE4
end_inst
end if ; </fold>
; </fold>
; <fold relation>
if(used inst$l4se) ; <fold >
inst l4se
overify TAG_LONG4, TAG_LONG4
vmovdqu ymm0, [rsp+$10]
vmovdqu ymm1, [rsp+$00]
vpcmpeqq ymm0, ymm0, ymm1
vmovmskpd eax, ymm0
cmp eax, $0f
sete al
movsx eax, al
vmovd xmm0, eax
vmovdqa xword[rsp+$30], xmm0
pop3set TAG_INT
end_inst
end if ; </fold>
if(used inst$l4sne) ; <fold >
inst l4sne
overify TAG_LONG4, TAG_LONG4
vmovdqu ymm0, [rsp+$10]
vmovdqu ymm1, [rsp+$00]
vpcmpeqq ymm0, ymm0, ymm1
vmovmskpd eax, ymm0
cmp eax, $0f
setne al
movsx eax, al
vmovd xmm0, eax
vmovdqa xword[rsp+$30], xmm0
pop3set TAG_INT
end_inst
end if ; </fold>
; </fold>
; <fold bitwise>
if(used inst$l4not) ; <fold >
inst l4not
overify TAG_LONG4
vmovdqu ymm0, [rsp]
vpxor ymm0, ymm0, [l8.00]
vmovdqu yword[rsp], ymm0
end_inst
end if ; </fold>
if(used inst$l4and) ; <fold >
inst l4and
overify TAG_LONG4, TAG_LONG4
vmovdqu ymm0, [rsp+$20]
vmovdqu ymm1, [rsp+$00]
vpand ymm0, ymm0, ymm1
vmovdqu yword[rsp+$20], ymm0
pop2set
end_inst
end if ; </fold>
if(used inst$l4or) ; <fold >
inst l4or
overify TAG_LONG4, TAG_LONG4
vmovdqu ymm0, [rsp+$20]
vmovdqu ymm1, [rsp+$00]
vpor ymm0, ymm0, ymm1
vmovdqu yword[rsp+$20], ymm0
pop2set
end_inst
end if ; </fold>
if(used inst$l4xor) ; <fold >
inst l4xor
overify TAG_LONG4, TAG_LONG4
vmovdqu ymm0, [rsp+$20]
vmovdqu ymm1, [rsp+$00]
vpxor ymm0, ymm0, ymm1
vmovdqu yword[rsp+$20], ymm0
pop2set
end_inst
end if ; </fold>
; </fold>
; <fold scalar>
if(used inst$l4sneg | used inst$l4vneg) ; <fold >
inst l4sneg, l4vneg
overify TAG_LONG4
vmovdqu ymm0, [rsp]
vpxor ymm1, ymm0, ymm0
vpsubq ymm0, ymm1, ymm0
vmovdqu yword[rsp], ymm0
end_inst
end if ; </fold>
if(used inst$l4smul) ; <fold >
inst l4smul
overify TAG_LONG4, TAG_LONG4
vmovdqu ymm0, [rsp+$20]
vmovdqu ymm1, [rsp+$00]
vshufi64x2 ymm4, ymm1, ymm1, $02
vshufi64x2 ymm6, ymm4, ymm4, $01
vshufpd ymm5, ymm4, ymm4, $05
vshufpd ymm7, ymm6, ymm6, $05
vpmullq ymm4, ymm4, [l4.q0]
vpmullq ymm5, ymm5, [l4.q1]
vpmullq ymm6, ymm6, [l4.q2]
vpmullq ymm7, ymm7, [l4.q3]
vpmullq ymm3, ymm0, ymm7
vpmullq ymm2, ymm0, ymm6
vpmullq ymm1, ymm0, ymm5
vpmullq ymm0, ymm0, ymm4
vextracti128 xmm4, ymm0, $01
vextracti128 xmm5, ymm1, $01
vextracti128 xmm6, ymm2, $01
vextracti128 xmm7, ymm3, $01
vinserti128 ymm0, ymm0, xmm2, $01
vinserti128 ymm2, ymm1, xmm3, $01
vinserti128 ymm1, ymm4, xmm6, $01
vinserti128 ymm3, ymm5, xmm7, $01
vpaddq ymm0, ymm0, ymm1
vpaddq ymm1, ymm2, ymm3
vshufpd ymm2, ymm0, ymm1, $00
vshufpd ymm3, ymm0, ymm1, $0f
vpaddq ymm0, ymm2, ymm3
vmovdqu yword[rsp+$20], ymm0
pop2set
end_inst
end if ; </fold>
if(used inst$l4sadd | used inst$l4vadd) ; <fold >
inst l4sadd, l4vadd
overify TAG_LONG4, TAG_LONG4
vmovdqu ymm0, [rsp+$20]
vmovdqu ymm1, [rsp+$00]
vpaddq ymm0, ymm0, ymm1
vmovdqu yword[rsp+$20], ymm0
pop2set
end_inst
end if ; </fold>
if(used inst$l4ssub | used inst$l4vsub) ; <fold >
inst l4ssub, l4vsub
overify TAG_LONG4, TAG_LONG4
vmovdqu ymm0, [rsp+$20]
vmovdqu ymm1, [rsp+$00]
vpsubq ymm0, ymm0, ymm1
vmovdqu yword[rsp+$20], ymm0
pop2set
end_inst
end if ; </fold>
if(used inst$l4ssar | used inst$l4vsar) ; <fold >
inst l4ssar, l4vsar
overify TAG_LONG4, TAG_INT
mov ecx, [rsp]
and ecx, $3f
vmovdqu ymm0, [rsp+$10]
vmovd xmm1, ecx
vpsraq ymm0, ymm0, xmm1
vmovdqu yword[rsp+$10], ymm0
pop1set
end_inst
end if ; </fold>
if(used inst$l4ssal | used inst$l4vsal) ; <fold >
inst l4ssal, l4vsal
overify TAG_LONG4, TAG_INT
mov ecx, [rsp]
and ecx, $3f
vmovdqu ymm0, [rsp+$10]
vmovd xmm1, ecx
vpsllq ymm0, ymm0, xmm1
vmovdqu yword[rsp+$10], ymm0
pop1set
end_inst
end if ; </fold>
if(used inst$l4sshr | used inst$l4vshr) ; <fold >
inst l4sshr, l4vshr
overify TAG_LONG4, TAG_INT
mov ecx, [rsp]
and ecx, $3f
vmovdqu ymm0, [rsp+$10]
vmovd xmm1, ecx
vpsrlq ymm0, ymm0, xmm1
vmovdqu yword[rsp+$10], ymm0
pop1set
end_inst
end if ; </fold>
; </fold>
; <fold vector>
if(used inst$l4vpack) ; <fold >
inst l4vpack
overify TAG_LONG4
vmovdqu ymm0, [rsp]
vpxor ymm1, ymm0, ymm0
vpcmpgtq ymm1, ymm1, ymm0
vpcmpgtq ymm2, ymm0, [l8.01]
vpandn ymm0, ymm1, ymm0
vpor ymm0, ymm2, ymm0
vshufps ymm0, ymm0, ymm0, $d8
vextracti128 xmm1, ymm0, $01
vpand xmm0, xmm0, [i8.04]
vpslldq xmm1, xmm1, $08
vpor xmm0, xmm0, xmm1
vmovdqa xword[rsp+$10], xmm0
pop1set TAG_INT4
end_inst
end if ; </fold>
if(used inst$l4vmul) ; <fold >
inst l4vmul
overify TAG_LONG4, TAG_LONG4
vmovdqu ymm0, [rsp+$20]
vmovdqu ymm1, [rsp+$00]
vpmullq ymm0, ymm0, ymm1
vmovdqu yword[rsp+$20], ymm0
pop2set
end_inst
end if ; </fold>
if(used inst$l4vg) ; <fold >
inst l4vg
overify TAG_LONG4, TAG_LONG4
vmovdqu ymm0, [rsp+$20]
vmovdqu ymm1, [rsp+$00]
vpcmpgtq ymm0, ymm0, ymm1
vmovdqu yword[rsp+$20], ymm0
pop2set
end_inst
end if ; </fold>
if(used inst$l4vge) ; <fold >
inst l4vge
overify TAG_LONG4, TAG_LONG4
vmovdqu ymm0, [rsp+$20]
vmovdqu ymm1, [rsp+$00]
vpcmpgtq ymm0, ymm1, ymm0
vpxor ymm0, ymm0, [l8.00]
vmovdqu yword[rsp+$20], ymm0
pop2set
end_inst
end if ; </fold>
if(used inst$l4vl) ; <fold >
inst l4vl
overify TAG_LONG4, TAG_LONG4
vmovdqu ymm0, [rsp+$20]
vmovdqu ymm1, [rsp+$00]
vpcmpgtq ymm0, ymm1, ymm0
vmovdqu yword[rsp+$20], ymm0
pop2set
end_inst
end if ; </fold>
if(used inst$l4vle) ; <fold >
inst l4vle
overify TAG_LONG4, TAG_LONG4
vmovdqu ymm0, [rsp+$20]
vmovdqu ymm1, [rsp+$00]
vpcmpgtq ymm0, ymm0, ymm1
vpxor ymm0, ymm0, [l8.00]
vmovdqu yword[rsp+$20], ymm0
pop2set
end_inst
end if ; </fold>
if(used inst$l4ve) ; <fold >
inst l4ve
overify TAG_LONG4, TAG_LONG4
vmovdqu ymm0, [rsp+$20]
vmovdqu ymm1, [rsp+$00]
vpcmpeqq ymm0, ymm0, ymm1
vmovdqu yword[rsp+$20], ymm0
pop2set
end_inst
end if ; </fold>
if(used inst$l4vne) ; <fold >
inst l4vne
overify TAG_LONG4, TAG_LONG4
vmovdqu ymm0, [rsp+$20]
vmovdqu ymm1, [rsp+$00]
vpcmpeqq ymm0, ymm0, ymm1
vpxor ymm0, ymm0, [l8.00]
vmovdqu yword[rsp+$20], ymm0
pop2set
end_inst
end if ; </fold>
; </fold>
