instruction.long2.inc

Переключить прокрутку окна
Загрузить этот исходный код

;
 ;  Исходный код среды исполнения ПВТ-ОО.
 ;
 ;  Этот исходный код является частью проекта ПВТ-ОО.
 ;
 ;  Copyright © 2021 Малик Разработчик
 ;
 ;  Это свободная программа: вы можете перераспространять её и/или
 ;  изменять её на условиях Меньшей Стандартной общественной лицензии GNU в том виде,
 ;  в каком она была опубликована Фондом свободного программного обеспечения;
 ;  либо версии 3 лицензии, либо (по вашему выбору) любой более поздней версии.
 ;
 ;  Эта программа распространяется в надежде, что она может быть полезна,
 ;  но БЕЗО ВСЯКИХ ГАРАНТИЙ; даже без неявной гарантии ТОВАРНОГО ВИДА
 ;  или ПРИГОДНОСТИ ДЛЯ ОПРЕДЕЛЁННЫХ ЦЕЛЕЙ. Подробнее см. в Меньшей Стандартной
 ;  общественной лицензии GNU.
 ;
 ;  Вы должны были получить копию Меньшей Стандартной общественной лицензии GNU
 ;  вместе с этой программой. Если это не так, см.
 ;  <http://www.gnu.org/licenses/>.
;

; <fold push/pop/peek>
    if(used inst$l2push) ; <fold >
        inst l2push ; (value in xmm0)
                    push1
                    vmovdqa xword[rsp], xmm0
                    set     TAG_LONG2
        end_inst
    end if ; </fold>

    if(used inst$l2pop) ; <fold >
        inst l2pop ; (): value in xmm0
                    overify TAG_LONG2
                    vmovdqa xmm0, [rsp]
                    pop1set
        end_inst
    end if ; </fold>
; </fold>

; <fold conversion>
    if(used inst$l2tob2) ; <fold >
        inst l2tob2
                    overify TAG_LONG2
                    vmovdqa xmm0, [rsp]
                    vpand   xmm0, xmm0, [l8.03]
                    vshufps xmm0, xmm0, xmm0, $d8
                    vpxor   xmm1, xmm0, xmm0
                    vpackusdw xmm0, xmm0, xmm1
                    vpackuswb xmm0, xmm0, xmm1
                    vmovdqa xword[rsp], xmm0
                    set     TAG_BYTE2
        end_inst
    end if ; </fold>

    if(used inst$l2tos2) ; <fold >
        inst l2tos2
                    overify TAG_LONG2
                    vmovdqa xmm0, [rsp]
                    vpand   xmm0, xmm0, [l8.02]
                    vshufps xmm0, xmm0, xmm0, $d8
                    vpxor   xmm1, xmm0, xmm0
                    vpackusdw xmm0, xmm0, xmm1
                    vmovdqa xword[rsp], xmm0
                    set     TAG_SHORT2
        end_inst
    end if ; </fold>

    if(used inst$l2toi2) ; <fold >
        inst l2toi2
                    overify TAG_LONG2
                    vmovdqa xmm0, [rsp]
                    vpand   xmm0, xmm0, [l8.01]
                    vshufps xmm0, xmm0, xmm0, $d8
                    vmovdqa xword[rsp], xmm0
                    set     TAG_INT2
        end_inst
    end if ; </fold>

    if(used inst$l2tol) ; <fold >
        inst l2tol
                    overify TAG_LONG2
                    vmovq   xmm0, [rsp]
                    vmovdqa xword[rsp], xmm0
                    set     TAG_LONG
        end_inst
    end if ; </fold>

    if(used inst$l2tol4) ; <fold >
        inst l2tol4
                    overify TAG_LONG2
                    push1
                    vmovdqa xmm0, [rsp+$10]
                    vmovdqu yword[rsp], ymm0
                    set     TAG_LONG4
        end_inst
    end if ; </fold>

    if(used inst$l2tol8) ; <fold >
        inst l2tol8
                    overify TAG_LONG2
                    push3
                    vmovdqa xmm0, [rsp+$30]
                    vmovdqu64 zword[rsp], zmm0
                    set     TAG_LONG8
        end_inst
    end if ; </fold>

    if(used inst$l2tof2) ; <fold >
        inst l2tof2
                    overify TAG_LONG2
                    vcvtqq2ps xmm0, xword[rsp]
                    vmovdqa xword[rsp], xmm0
                    set     TAG_FLOAT2
        end_inst
    end if ; </fold>

    if(used inst$l2tod2) ; <fold >
        inst l2tod2
                    overify TAG_LONG2
                    vcvtqq2pd xmm0, [rsp]
                    vmovdqa xword[rsp], xmm0
                    set     TAG_DOUBLE2
        end_inst
    end if ; </fold>
; </fold>

; <fold relation>
    if(used inst$l2se) ; <fold >
        inst l2se
                    overify TAG_LONG2, TAG_LONG2
                    vmovdqa xmm0, [rsp+$10]
                    vpcmpeqq xmm0, xmm0, [rsp]
                    vmovmskpd eax, xmm0
                    cmp     eax, $03
                    sete    al
                    movsx   eax, al
                    vmovd   xmm0, eax
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set TAG_INT
        end_inst
    end if ; </fold>

    if(used inst$l2sne) ; <fold >
        inst l2sne
                    overify TAG_LONG2, TAG_LONG2
                    vmovdqa xmm0, [rsp+$10]
                    vpcmpeqq xmm0, xmm0, [rsp]
                    vmovmskpd eax, xmm0
                    cmp     eax, $03
                    setne   al
                    movsx   eax, al
                    vmovd   xmm0, eax
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set TAG_INT
        end_inst
    end if ; </fold>
; </fold>

; <fold bitwise>
    if(used inst$l2not) ; <fold >
        inst l2not
                    overify TAG_LONG2
                    vmovdqa xmm0, [rsp]
                    vpxor   xmm0, xmm0, [l8.00]
                    vmovdqa xword[rsp], xmm0
        end_inst
    end if ; </fold>

    if(used inst$l2and) ; <fold >
        inst l2and
                    overify TAG_LONG2, TAG_LONG2
                    vmovdqa xmm0, [rsp+$10]
                    vpand   xmm0, xmm0, [rsp]
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>

    if(used inst$l2or) ; <fold >
        inst l2or
                    overify TAG_LONG2, TAG_LONG2
                    vmovdqa xmm0, [rsp+$10]
                    vpor    xmm0, xmm0, [rsp]
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>

    if(used inst$l2xor) ; <fold >
        inst l2xor
                    overify TAG_LONG2, TAG_LONG2
                    vmovdqa xmm0, [rsp+$10]
                    vpxor   xmm0, xmm0, [rsp]
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>
; </fold>

; <fold scalar>
    if(used inst$l2sneg | used inst$l2vneg) ; <fold >
        inst l2sneg, l2vneg
                    overify TAG_LONG2
                    vpxor   xmm0, xmm0, xmm0
                    vpsubq  xmm0, xmm0, [rsp]
                    vmovdqa xword[rsp], xmm0
        end_inst
    end if ; </fold>

    if(used inst$l2smul) ; <fold >
        inst l2smul
                    overify TAG_LONG2, TAG_LONG2
                    vmovdqa xmm0, [rsp+$10]
                    vmovdqa xmm1, [rsp+$00]
                    vshufpd xmm2, xmm1, xmm1, $02
                    vshufpd xmm3, xmm2, xmm2, $01
                    vpmullq xmm2, xmm2, [l2.c0]
                    vpmullq xmm1, xmm0, xmm3
                    vpmullq xmm0, xmm0, xmm2
                    vshufpd xmm2, xmm0, xmm1, $00
                    vshufpd xmm3, xmm0, xmm1, $03
                    vpaddq  xmm0, xmm2, xmm3
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>

    if(used inst$l2sadd | used inst$l2vadd) ; <fold >
        inst l2sadd, l2vadd
                    overify TAG_LONG2, TAG_LONG2
                    vmovdqa xmm0, [rsp+$10]
                    vpaddq  xmm0, xmm0, [rsp]
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>

    if(used inst$l2ssub | used inst$l2vsub) ; <fold >
        inst l2ssub, l2vsub
                    overify TAG_LONG2, TAG_LONG2
                    vmovdqa xmm0, [rsp+$10]
                    vpsubq  xmm0, xmm0, [rsp]
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>

    if(used inst$l2ssar | used inst$l2vsar) ; <fold >
        inst l2ssar, l2vsar
                    overify TAG_LONG2, TAG_INT
                    mov     ecx, [rsp]
                    and     ecx, $3f
                    vmovdqa xmm0, [rsp+$10]
                    vmovd   xmm1, ecx
                    vpsraq  xmm0, xmm0, xmm1
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>

    if(used inst$l2ssal | used inst$l2vsal) ; <fold >
        inst l2ssal, l2vsal
                    overify TAG_LONG2, TAG_INT
                    mov     ecx, [rsp]
                    and     ecx, $3f
                    vmovdqa xmm0, [rsp+$10]
                    vmovd   xmm1, ecx
                    vpsllq  xmm0, xmm0, xmm1
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>

    if(used inst$l2sshr | used inst$l2vshr) ; <fold >
        inst l2sshr, l2vshr
                    overify TAG_LONG2, TAG_INT
                    mov     ecx, [rsp]
                    and     ecx, $3f
                    vmovdqa xmm0, [rsp+$10]
                    vmovd   xmm1, ecx
                    vpsrlq  xmm0, xmm0, xmm1
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>
; </fold>

; <fold vector>
    if(used inst$l2vpack) ; <fold >
        inst l2vpack
                    overify TAG_LONG2
                    vmovdqa xmm0, [rsp]
                    vpxor   xmm1, xmm0, xmm0
                    vpcmpgtq xmm1, xmm1, xmm0
                    vpcmpgtq xmm2, xmm0, [l8.01]
                    vpandn  xmm0, xmm1, xmm0
                    vpor    xmm0, xmm2, xmm0
                    vshufps xmm0, xmm0, xmm0, $d8
                    vpand   xmm0, xmm0, [i8.04]
                    set     TAG_INT2
        end_inst
    end if ; </fold>

    if(used inst$l2vmul) ; <fold >
        inst l2vmul
                    overify TAG_LONG2, TAG_LONG2
                    vmovdqa xmm0, [rsp+$10]
                    vpmullq xmm0, xmm0, [rsp]
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>

    if(used inst$l2vg) ; <fold >
        inst l2vg
                    overify TAG_LONG2, TAG_LONG2
                    vmovdqa xmm0, [rsp+$10]
                    vpcmpgtq xmm0, xmm0, [rsp]
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>

    if(used inst$l2vge) ; <fold >
        inst l2vge
                    overify TAG_LONG2, TAG_LONG2
                    vmovdqa xmm0, [rsp]
                    vpcmpgtq xmm0, xmm0, [rsp+$10]
                    vpxor   xmm0, xmm0, [l8.00]
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>

    if(used inst$l2vl) ; <fold >
        inst l2vl
                    overify TAG_LONG2, TAG_LONG2
                    vmovdqa xmm0, [rsp]
                    vpcmpgtq xmm0, xmm0, [rsp+$10]
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>

    if(used inst$l2vle) ; <fold >
        inst l2vle
                    overify TAG_LONG2, TAG_LONG2
                    vmovdqa xmm0, [rsp+$10]
                    vpcmpgtq xmm0, xmm0, [rsp]
                    vpxor   xmm0, xmm0, [l8.00]
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>

    if(used inst$l2ve) ; <fold >
        inst l2ve
                    overify TAG_LONG2, TAG_LONG2
                    vmovdqa xmm0, [rsp+$10]
                    vpcmpeqq xmm0, xmm0, [rsp]
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>

    if(used inst$l2vne) ; <fold >
        inst l2vne
                    overify TAG_LONG2, TAG_LONG2
                    vmovdqa xmm0, [rsp+$10]
                    vpcmpeqq xmm0, xmm0, [rsp]
                    vpxor   xmm0, xmm0, [l8.00]
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>
; </fold>