instruction.float.inc

Переключить прокрутку окна
Загрузить этот исходный код

;
 ;  Исходный код среды исполнения ПВТ-ОО.
 ;
 ;  Этот исходный код является частью проекта ПВТ-ОО.
 ;
 ;  Copyright © 2021 Малик Разработчик
 ;
 ;  Это свободная программа: вы можете перераспространять её и/или
 ;  изменять её на условиях Меньшей Стандартной общественной лицензии GNU в том виде,
 ;  в каком она была опубликована Фондом свободного программного обеспечения;
 ;  либо версии 3 лицензии, либо (по вашему выбору) любой более поздней версии.
 ;
 ;  Эта программа распространяется в надежде, что она может быть полезна,
 ;  но БЕЗО ВСЯКИХ ГАРАНТИЙ; даже без неявной гарантии ТОВАРНОГО ВИДА
 ;  или ПРИГОДНОСТИ ДЛЯ ОПРЕДЕЛЁННЫХ ЦЕЛЕЙ. Подробнее см. в Меньшей Стандартной
 ;  общественной лицензии GNU.
 ;
 ;  Вы должны были получить копию Меньшей Стандартной общественной лицензии GNU
 ;  вместе с этой программой. Если это не так, см.
 ;  <http://www.gnu.org/licenses/>.
;

; <fold push/pop/peek>
    if(used inst$fpush) ; <fold >
        inst fpush ; (value in xmm0)
                    push1
                    vmovdqa xword[rsp], xmm0
                    set     TAG_FLOAT
        end_inst
    end if ; </fold>

    if(used inst$fpop) ; <fold >
        inst fpop ; (): value in xmm0
                    overify TAG_FLOAT
                    vmovd   xmm0, [rsp]
                    pop1set
        end_inst
    end if ; </fold>
; </fold>

; <fold conversion>
    if(used inst$ftoi) ; <fold >
        inst ftoi
                    overify TAG_FLOAT
                    vmovd   xmm0, [rsp]
                    vcvttss2si eax, xmm0
                    vmovd   xmm1, eax
                    vmovd   xmm2, [f8.00]
                    vcmpss  xmm2, xmm2, xmm0, $02
                    vcmpss  xmm3, xmm0, xmm0, $07
                    vpaddd  xmm0, xmm1, xmm2
                    vpand   xmm0, xmm0, xmm3
                    vmovdqa xword[rsp], xmm0
                    set     TAG_INT
        end_inst
    end if ; </fold>

    if(used inst$ftol) ; <fold >
        inst ftol
                    overify TAG_FLOAT
                    vmovd   xmm0, [rsp]
                    vcvtss2sd xmm0, xmm0, xmm0
                    vcvttsd2si rax, xmm0
                    vmovq   xmm1, rax
                    vmovq   xmm2, [d8.01]
                    vcmpsd  xmm2, xmm2, xmm0, $02
                    vcmpsd  xmm3, xmm0, xmm0, $07
                    vpaddq  xmm0, xmm1, xmm2
                    vpand   xmm0, xmm0, xmm3
                    vmovdqa xword[rsp], xmm0
                    set     TAG_LONG
        end_inst
    end if ; </fold>

    if(used inst$ftof2) ; <fold >
        inst ftof2
                    overify TAG_FLOAT
                    vmovd   xmm0, [rsp]
                    vmovdqa xword[rsp], xmm0
                    set     TAG_FLOAT2
        end_inst
    end if ; </fold>

    if(used inst$ftof4) ; <fold >
        inst ftof4
                    overify TAG_FLOAT
                    vmovd   xmm0, [rsp]
                    vmovdqa xword[rsp], xmm0
                    set     TAG_FLOAT4
        end_inst
    end if ; </fold>

    if(used inst$ftof8) ; <fold >
        inst ftof8
                    overify TAG_FLOAT
                    push1
                    vmovd   xmm0, [rsp+$10]
                    vmovdqu yword[rsp], ymm0
                    set     TAG_FLOAT8
        end_inst
    end if ; </fold>

    if(used inst$ftod) ; <fold >
        inst ftod
                    overify TAG_FLOAT
                    vpxor   xmm0, xmm0, xmm0
                    vcvtss2sd xmm0, xmm0, [rsp]
                    vmovdqa xword[rsp], xmm0
                    set     TAG_DOUBLE
        end_inst
    end if ; </fold>

    if(used inst$ftox) ; <fold >
        inst ftox
                    overify TAG_FLOAT
                    fld     dword[rsp]
                    mov     qword[rsp+$08], $00
                    fstp    tbyte[rsp+$00]
                    set     TAG_REAL
        end_inst
    end if ; </fold>
; </fold>

; <fold relation>
    if(used inst$fcmpg) ; <fold >
        inst fcmpg
                    overify TAG_FLOAT, TAG_FLOAT
                    vmovd   xmm0, [rsp+$10]
                    vcomiss xmm0, [rsp+$00]
                    jp      .G
                    jc      .L
                    jz      .E
            .G:     mov     eax, $01
                    jmp     @F
            .L:     mov     eax, -$01
                    jmp     @F
            .E:     xor     eax, eax
            @@:     mov     dword[rsp+$10], eax
                    pop1set TAG_INT
        end_inst
    end if ; </fold>

    if(used inst$fcmpl) ; <fold >
        inst fcmpl
                    overify TAG_FLOAT, TAG_FLOAT
                    vmovd   xmm0, [rsp+$10]
                    vcomiss xmm0, [rsp+$00]
                    jp      .L
                    jc      .L
                    jz      .E
                    mov     eax, $01
                    jmp     @F
            .L:     mov     eax, -$01
                    jmp     @F
            .E:     xor     eax, eax
            @@:     mov     dword[rsp+$10], eax
                    pop1set TAG_INT
        end_inst
    end if ; </fold>
; </fold>

; <fold scalar>
    if(used inst$fsneg | used inst$fvneg) ; <fold >
        inst fsneg, fvneg
                    overify TAG_FLOAT
                    vpxor   xmm0, xmm0, xmm0
                    vsubss  xmm0, xmm0, [rsp]
                    vmovdqa xword[rsp], xmm0
        end_inst
    end if ; </fold>

    if(used inst$fsmul | used inst$fvmul) ; <fold >
        inst fsmul, fvmul
                    overify TAG_FLOAT, TAG_FLOAT
                    vmovd   xmm0, [rsp+$10]
                    vmulss  xmm0, xmm0, [rsp]
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>

    if(used inst$fsdiv | used inst$fsdivu | used inst$fvdiv) ; <fold >
        inst fsdiv, fsdivu, fvdiv
                    overify TAG_FLOAT, TAG_FLOAT
                    vmovd   xmm0, [rsp+$10]
                    vdivss  xmm0, xmm0, [rsp]
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>

    if(used inst$fsrem | used inst$fsremu) ; <fold >
        inst fsrem, fsremu
                    overify TAG_FLOAT, TAG_FLOAT
                    fld     dword[rsp+$00]
                    fld     dword[rsp+$10]
            @@:     fprem
                    fnstsw  ax
                    test    ax, $0400
                    jnz     @B
                    fstp    st1
                    fstp    dword[rsp+$10]
                    pop1set
        end_inst
    end if ; </fold>

    if(used inst$fsadd | used inst$fvadd) ; <fold >
        inst fsadd, fvadd
                    overify TAG_FLOAT, TAG_FLOAT
                    vmovd   xmm0, [rsp+$10]
                    vaddss  xmm0, xmm0, [rsp]
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>

    if(used inst$fssub | used inst$fvsub) ; <fold >
        inst fssub, fvsub
                    overify TAG_FLOAT, TAG_FLOAT
                    vmovd   xmm0, [rsp+$10]
                    vsubss  xmm0, xmm0, [rsp]
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>
; </fold>

; <fold vector>
    if(used inst$fvg) ; <fold >
        inst fvg
                    overify TAG_FLOAT, TAG_FLOAT
                    vmovd   xmm0, [rsp+$10]
                    vmovd   xmm1, [rsp+$00]
                    vcmpss  xmm0, xmm1, xmm0, $01
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set TAG_INT
        end_inst
    end if ; </fold>

    if(used inst$fvge) ; <fold >
        inst fvge
                    overify TAG_FLOAT, TAG_FLOAT
                    vmovd   xmm0, [rsp+$10]
                    vmovd   xmm1, [rsp+$00]
                    vcmpss  xmm0, xmm1, xmm0, $02
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set TAG_INT
        end_inst
    end if ; </fold>

    if(used inst$fvl) ; <fold >
        inst fvl
                    overify TAG_FLOAT, TAG_FLOAT
                    vmovd   xmm0, [rsp+$10]
                    vmovd   xmm1, [rsp+$00]
                    vcmpss  xmm0, xmm0, xmm1, $01
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set TAG_INT
        end_inst
    end if ; </fold>

    if(used inst$fvle) ; <fold >
        inst fvle
                    overify TAG_FLOAT, TAG_FLOAT
                    vmovd   xmm0, [rsp+$10]
                    vmovd   xmm1, [rsp+$00]
                    vcmpss  xmm0, xmm0, xmm1, $02
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set TAG_INT
        end_inst
    end if ; </fold>

    if(used inst$fve) ; <fold >
        inst fve
                    overify TAG_FLOAT, TAG_FLOAT
                    vmovd   xmm0, [rsp+$10]
                    vmovd   xmm1, [rsp+$00]
                    vcmpss  xmm0, xmm0, xmm1, $00
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set TAG_INT
        end_inst
    end if ; </fold>

    if(used inst$fvne) ; <fold >
        inst fvne
                    overify TAG_FLOAT, TAG_FLOAT
                    vmovd   xmm0, [rsp+$10]
                    vmovd   xmm1, [rsp+$00]
                    vcmpss  xmm0, xmm0, xmm1, $04
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set TAG_INT
        end_inst
    end if ; </fold>
; </fold>