instruction.double2.inc

Переключить прокрутку окна
Загрузить этот исходный код

;
 ;  Исходный код среды исполнения ПВТ-ОО.
 ;
 ;  Этот исходный код является частью проекта ПВТ-ОО.
 ;
 ;  Copyright © 2021 Малик Разработчик
 ;
 ;  Это свободная программа: вы можете перераспространять её и/или
 ;  изменять её на условиях Меньшей Стандартной общественной лицензии GNU в том виде,
 ;  в каком она была опубликована Фондом свободного программного обеспечения;
 ;  либо версии 3 лицензии, либо (по вашему выбору) любой более поздней версии.
 ;
 ;  Эта программа распространяется в надежде, что она может быть полезна,
 ;  но БЕЗО ВСЯКИХ ГАРАНТИЙ; даже без неявной гарантии ТОВАРНОГО ВИДА
 ;  или ПРИГОДНОСТИ ДЛЯ ОПРЕДЕЛЁННЫХ ЦЕЛЕЙ. Подробнее см. в Меньшей Стандартной
 ;  общественной лицензии GNU.
 ;
 ;  Вы должны были получить копию Меньшей Стандартной общественной лицензии GNU
 ;  вместе с этой программой. Если это не так, см.
 ;  <http://www.gnu.org/licenses/>.
;

; <fold push/pop/peek>
    if(used inst$d2push) ; <fold >
        inst d2push ; (value in xmm0)
                    push1
                    vmovdqa xword[rsp], xmm0
                    set     TAG_DOUBLE2
        end_inst
    end if ; </fold>

    if(used inst$d2pop) ; <fold >
        inst d2pop ; (): value in xmm0
                    overify TAG_DOUBLE2
                    vmovdqa xmm0, [rsp]
                    pop1set
        end_inst
    end if ; </fold>
; </fold>

; <fold conversion>
    if(used inst$d2toi2) ; <fold >
        inst d2toi2
                    overify TAG_DOUBLE2
                    vmovdqa xmm0, [rsp]
                    vcvttpd2dq xmm1, xmm0
                    vmovdqa xmm2, [d8.00]
                    vmovq   xmm3, [i8.01]
                    vcmppd  k1, xmm2, xmm0, $02
                    vcmppd  k2, xmm0, xmm0, $07
                    vmovdqa32 xmm2{k1}{z}, xmm3
                    vmovdqa32 xmm3{k2}{z}, xmm3
                    vpaddd  xmm0, xmm1, xmm2
                    vpand   xmm0, xmm0, xmm3
                    vmovdqa xword[rsp], xmm0
                    set     TAG_INT2
        end_inst
    end if ; </fold>

    if(used inst$d2tol2) ; <fold >
        inst d2tol2
                    overify TAG_DOUBLE2
                    vmovdqa xmm0, [rsp]
                    vcvttpd2qq xmm1, xmm0
                    vmovdqa xmm2, [d8.01]
                    vcmppd  xmm2, xmm2, xmm0, $02
                    vcmppd  xmm3, xmm0, xmm0, $07
                    vpaddq  xmm0, xmm1, xmm2
                    vpand   xmm0, xmm0, xmm3
                    vmovdqa xword[rsp], xmm0
                    set     TAG_LONG2
        end_inst
    end if ; </fold>

    if(used inst$d2tof2) ; <fold >
        inst d2tof2
                    overify TAG_DOUBLE2
                    vcvtpd2ps xmm0, xword[rsp]
                    vmovdqa xword[rsp], xmm0
                    set     TAG_FLOAT2
        end_inst
    end if ; </fold>

    if(used inst$d2tod) ; <fold >
        inst d2tod
                    overify TAG_DOUBLE2
                    vmovq   xmm0, [rsp]
                    vmovdqa xword[rsp], xmm0
                    set     TAG_DOUBLE
        end_inst
    end if ; </fold>

    if(used inst$d2tod4) ; <fold >
        inst d2tod4
                    overify TAG_DOUBLE2
                    push1
                    vmovdqa xmm0, [rsp+$10]
                    vmovdqu yword[rsp], ymm0
                    set     TAG_DOUBLE4
        end_inst
    end if ; </fold>

    if(used inst$d2tod8) ; <fold >
        inst d2tod8
                    overify TAG_DOUBLE2
                    push3
                    vmovdqa xmm0, [rsp+$30]
                    vmovdqu64 zword[rsp], zmm0
                    set     TAG_DOUBLE8
        end_inst
    end if ; </fold>
; </fold>

; <fold relation>
    if(used inst$d2se) ; <fold >
        inst d2se
                    overify TAG_DOUBLE2, TAG_DOUBLE2
                    vmovdqa xmm0, [rsp+$10]
                    vcmppd  xmm0, xmm0, [rsp], $00
                    vmovmskpd eax, xmm0
                    cmp     eax, $03
                    sete    al
                    movsx   eax, al
                    vmovd   xmm0, eax
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set TAG_INT
        end_inst
    end if ; </fold>

    if(used inst$d2sne) ; <fold >
        inst d2sne
                    overify TAG_DOUBLE2, TAG_DOUBLE2
                    vmovdqa xmm0, [rsp+$10]
                    vcmppd  xmm0, xmm0, [rsp], $00
                    vmovmskpd eax, xmm0
                    cmp     eax, $03
                    setne   al
                    movsx   eax, al
                    vmovd   xmm0, eax
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set TAG_INT
        end_inst
    end if ; </fold>
; </fold>

; <fold scalar>
    if(used inst$d2sneg | used inst$d2vneg) ; <fold >
        inst d2sneg, d2vneg
                    overify TAG_DOUBLE2
                    vpxor   xmm0, xmm0, xmm0
                    vsubpd  xmm0, xmm0, [rsp]
                    vmovdqa xword[rsp], xmm0
        end_inst
    end if ; </fold>

    if(used inst$d2smul) ; <fold >
        inst d2smul
                    overify TAG_DOUBLE2, TAG_DOUBLE2
                    vmovdqa xmm0, [rsp+$10]
                    vmovdqa xmm1, [rsp+$00]
                    vshufpd xmm2, xmm1, xmm1, $02
                    vshufpd xmm3, xmm2, xmm2, $01
                    vmulpd  xmm2, xmm2, [d2.c0]
                    vmulpd  xmm1, xmm0, xmm3
                    vmulpd  xmm0, xmm0, xmm2
                    vhaddpd xmm0, xmm0, xmm1
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>

    if(used inst$d2sdiv) ; <fold >
        inst d2sdiv
                    overify TAG_DOUBLE2, TAG_DOUBLE2
                    vmovdqa xmm0, [rsp+$10]
                    vmovdqa xmm1, [rsp+$00]
                    vmulpd  xmm1, xmm1, [d2.c0]
                    vmulpd  xmm2, xmm1, xmm1
                    vhaddpd xmm2, xmm2, xmm2
                    vdivpd  xmm1, xmm1, xmm2
                    vshufpd xmm2, xmm1, xmm1, $02
                    vshufpd xmm3, xmm2, xmm2, $01
                    vmulpd  xmm2, xmm2, [d2.c0]
                    vmulpd  xmm1, xmm0, xmm3
                    vmulpd  xmm0, xmm0, xmm2
                    vhaddpd xmm0, xmm0, xmm1
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>

    if(used inst$d2sdivu) ; <fold >
        inst d2sdivu
                    overify TAG_DOUBLE2, TAG_DOUBLE2
                    vmovdqa xmm0, [rsp+$00]
                    vmovdqa xmm1, [rsp+$10]
                    vmulpd  xmm0, xmm0, [d2.c0]
                    vmulpd  xmm2, xmm0, xmm0
                    vhaddpd xmm2, xmm2, xmm2
                    vdivpd  xmm0, xmm0, xmm2
                    vshufpd xmm2, xmm1, xmm1, $02
                    vshufpd xmm3, xmm2, xmm2, $01
                    vmulpd  xmm2, xmm2, [d2.c0]
                    vmulpd  xmm1, xmm0, xmm3
                    vmulpd  xmm0, xmm0, xmm2
                    vhaddpd xmm0, xmm0, xmm1
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>

    if(used inst$d2sadd | used inst$d2vadd) ; <fold >
        inst d2sadd, d2vadd
                    overify TAG_DOUBLE2, TAG_DOUBLE2
                    vmovdqa xmm0, [rsp+$10]
                    vaddpd  xmm0, xmm0, [rsp]
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>

    if(used inst$d2ssub | used inst$d2vsub) ; <fold >
        inst d2ssub, d2vsub
                    overify TAG_DOUBLE2, TAG_DOUBLE2
                    vmovdqa xmm0, [rsp+$10]
                    vsubpd  xmm0, xmm0, [rsp]
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>
; </fold>

; <fold vector>
    if(used inst$d2vmul) ; <fold >
        inst d2vmul
                    overify TAG_DOUBLE2, TAG_DOUBLE2
                    vmovdqa xmm0, [rsp+$10]
                    vmulpd  xmm0, xmm0, [rsp]
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>

    if(used inst$d2vdiv) ; <fold >
        inst d2vdiv
                    overify TAG_DOUBLE2, TAG_DOUBLE2
                    vmovdqa xmm0, [rsp+$10]
                    vdivpd  xmm0, xmm0, [rsp]
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set
        end_inst
    end if ; </fold>

    if(used inst$d2vg) ; <fold >
        inst d2vg
                    overify TAG_DOUBLE2, TAG_DOUBLE2
                    vmovdqa xmm0, [rsp+$10]
                    vmovdqa xmm1, [rsp+$00]
                    vcmppd  xmm0, xmm1, xmm0, $01
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set TAG_LONG2
        end_inst
    end if ; </fold>

    if(used inst$d2vge) ; <fold >
        inst d2vge
                    overify TAG_DOUBLE2, TAG_DOUBLE2
                    vmovdqa xmm0, [rsp+$10]
                    vmovdqa xmm1, [rsp+$00]
                    vcmppd  xmm0, xmm1, xmm0, $02
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set TAG_LONG2
        end_inst
    end if ; </fold>

    if(used inst$d2vl) ; <fold >
        inst d2vl
                    overify TAG_DOUBLE2, TAG_DOUBLE2
                    vmovdqa xmm0, [rsp+$10]
                    vmovdqa xmm1, [rsp+$00]
                    vcmppd  xmm0, xmm0, xmm1, $01
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set TAG_LONG2
        end_inst
    end if ; </fold>

    if(used inst$d2vle) ; <fold >
        inst d2vle
                    overify TAG_DOUBLE2, TAG_DOUBLE2
                    vmovdqa xmm0, [rsp+$10]
                    vmovdqa xmm1, [rsp+$00]
                    vcmppd  xmm0, xmm0, xmm1, $02
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set TAG_LONG2
        end_inst
    end if ; </fold>

    if(used inst$d2ve) ; <fold >
        inst d2ve
                    overify TAG_DOUBLE2, TAG_DOUBLE2
                    vmovdqa xmm0, [rsp+$10]
                    vmovdqa xmm1, [rsp+$00]
                    vcmppd  xmm0, xmm0, xmm1, $00
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set TAG_LONG2
        end_inst
    end if ; </fold>

    if(used inst$d2vne) ; <fold >
        inst d2vne
                    overify TAG_DOUBLE2, TAG_DOUBLE2
                    vmovdqa xmm0, [rsp+$10]
                    vmovdqa xmm1, [rsp+$00]
                    vcmppd  xmm0, xmm0, xmm1, $04
                    vmovdqa xword[rsp+$10], xmm0
                    pop1set TAG_LONG2
        end_inst
    end if ; </fold>
; </fold>