Int4.inc

Переключить прокрутку окна
Загрузить этот исходный код

;
 ;  Исходный код среды исполнения ПВТ-ОО.
 ;
 ;  Этот исходный код является частью проекта ПВТ-ОО.
 ;
 ;  Copyright © 2021 Малик Разработчик
 ;
 ;  Это свободная программа: вы можете перераспространять её и/или
 ;  изменять её на условиях Меньшей Стандартной общественной лицензии GNU в том виде,
 ;  в каком она была опубликована Фондом свободного программного обеспечения;
 ;  либо версии 3 лицензии, либо (по вашему выбору) любой более поздней версии.
 ;
 ;  Эта программа распространяется в надежде, что она может быть полезна,
 ;  но БЕЗО ВСЯКИХ ГАРАНТИЙ; даже без неявной гарантии ТОВАРНОГО ВИДА
 ;  или ПРИГОДНОСТИ ДЛЯ ОПРЕДЕЛЁННЫХ ЦЕЛЕЙ. Подробнее см. в Меньшей Стандартной
 ;  общественной лицензии GNU.
 ;
 ;  Вы должны были получить копию Меньшей Стандартной общественной лицензии GNU
 ;  вместе с этой программой. Если это не так, см.
 ;  <http://www.gnu.org/licenses/>.
;

; <fold avt.lang.Int4 (natives)>

    method avt.lang.Int4$max$int4$int4$, \
                value0, int4, \
                value1, int4  ; returns int4 <fold >
                menter
                lverify value0, TAG_INT4
                lverify value1, TAG_INT4
                vmovdqa xmm0, [.value0]
                vpmaxsd xmm0, xmm0, [.value1]
                call    inst$i4push
                mleavex
                eleave
    ; </fold>

    method avt.lang.Int4$maxUnsigned$int4$int4$, \
                value0, int4, \
                value1, int4  ; returns int4 <fold >
                menter
                lverify value0, TAG_INT4
                lverify value1, TAG_INT4
                vmovdqa xmm0, [.value0]
                vpmaxud xmm0, xmm0, [.value1]
                call    inst$i4push
                mleavex
                eleave
    ; </fold>

    method avt.lang.Int4$min$int4$int4$, \
                value0, int4, \
                value1, int4  ; returns int4 <fold >
                menter
                lverify value0, TAG_INT4
                lverify value1, TAG_INT4
                vmovdqa xmm0, [.value0]
                vpminsd xmm0, xmm0, [.value1]
                call    inst$i4push
                mleavex
                eleave
    ; </fold>

    method avt.lang.Int4$minUnsigned$int4$int4$, \
                value0, int4, \
                value1, int4  ; returns int4 <fold >
                menter
                lverify value0, TAG_INT4
                lverify value1, TAG_INT4
                vmovdqa xmm0, [.value0]
                vpminud xmm0, xmm0, [.value1]
                call    inst$i4push
                mleavex
                eleave
    ; </fold>

    method avt.lang.Int4$rotateLeft$int4$int$, \
                value, int4, \
                bits, int  ; returns int4 <fold >
                menter
                lverify value, TAG_INT4
                lverify bits, TAG_INT
                mov     r1d, [.bits]
                and     r1d, $1f
                mov     r2d, $20
                sub     r2d, r1d
                vmovdqa xmm3, [.value]
                vmovd   xmm2, r2d
                vmovd   xmm1, r1d
                vpslld  xmm0, xmm3, xmm1
                vpsrld  xmm3, xmm3, xmm2
                vpor    xmm0, xmm0, xmm3
                call    inst$i4push
                mleavex
                eleave
    ; </fold>

    method avt.lang.Int4$rotateRight$int4$int$, \
                value, int4, \
                bits, int  ; returns int4 <fold >
                menter
                lverify value, TAG_INT4
                lverify bits, TAG_INT
                mov     r1d, [.bits]
                and     r1d, $1f
                mov     r2d, $20
                sub     r2d, r1d
                vmovdqa xmm3, [.value]
                vmovd   xmm2, r2d
                vmovd   xmm1, r1d
                vpsrld  xmm0, xmm3, xmm1
                vpslld  xmm3, xmm3, xmm2
                vpor    xmm0, xmm0, xmm3
                call    inst$i4push
                mleavex
                eleave
    ; </fold>

    method avt.lang.Int4$high$int4$, \
                value, int4  ; returns int2 <fold >
                menter
                lverify value, TAG_INT4
                i2load  [.value+$08]
                mleavex
                eleave
    ; </fold>

    method avt.lang.Int4$create$int2$int2$, \
                value0, int2, \
                value1, int2  ; returns int4 <fold >
                menter
                lverify value0, TAG_INT2
                lverify value1, TAG_INT2
                iload   [.value0+$00]
                iload   [.value0+$04]
                iload   [.value1+$00]
                iload   [.value1+$04]
                newvectori4
                mleavex
                eleave
    ; </fold>

    method avt.lang.Int4$setElement$int4$int$int$, \
                value, int4, \
                index, int, \
                element, int  ; returns int4 <fold >
                menter
                lverify value, TAG_INT4
                lverify index, TAG_INT
                lverify element, TAG_INT
                mov     r0d, [.index]
                cmp     r0d, $00
                jl      .L.000
                cmp     r0d, $04
                jl      .L.001
        .L.000: call    inst$throwVectorIndexOutOfBoundsException
        .L.001: mov     r1d, [.element]
                mov     dword[.value+r0*4], r1d
                i4load  [.value]
                mleavex
                eleave
    ; </fold>

    method avt.lang.Int4$toShort8Bits$int4$, \
                value, int4  ; returns short8 <fold >
                menter
                lverify value, TAG_INT4
                s8load  [.value]
                mleavex
                eleave
    ; </fold>

    method avt.lang.Int4$toLong2Bits$int4$, \
                value, int4  ; returns long2 <fold >
                menter
                lverify value, TAG_INT4
                l2load  [.value]
                mleavex
                eleave
    ; </fold>

    method avt.lang.Int4$toFloat4Bits$int4$, \
                value, int4  ; returns float4 <fold >
                menter
                lverify value, TAG_INT4
                f4load  [.value]
                mleavex
                eleave
    ; </fold>
; </fold>