;
; Реализация среды исполнения языка программирования
; Объектно-ориентированный продвинутый векторный транслятор
;
; Copyright © 2021, 2024 Малик Разработчик
;
; Это свободная программа: вы можете перераспространять ее и/или изменять
; ее на условиях Меньшей Стандартной общественной лицензии GNU в том виде,
; в каком она была опубликована Фондом свободного программного обеспечения;
; либо версии 3 лицензии, либо (по вашему выбору) любой более поздней версии.
;
; Эта программа распространяется в надежде, что она будет полезной,
; но БЕЗО ВСЯКИХ ГАРАНТИЙ; даже без неявной гарантии ТОВАРНОГО ВИДА
; или ПРИГОДНОСТИ ДЛЯ ОПРЕДЕЛЕННЫХ ЦЕЛЕЙ. Подробнее см. в Меньшей Стандартной
; общественной лицензии GNU.
;
; Вы должны были получить копию Меньшей Стандартной общественной лицензии GNU
; вместе с этой программой. Если это не так, см.
; <https://www.gnu.org/licenses/>.
;
; <fold avt.lang.Short8 — родной код>
if(used avt.lang.Short8$low$short8$) ; <fold returns short4>
fast avt.lang.Short8$low$short8$, \
value, short8
fenter
vmovq xmm0, [.value+$00]
fleave
end if ; </fold>
if(used avt.lang.Short8$high$short8$) ; <fold returns short4>
fast avt.lang.Short8$high$short8$, \
value, short8
fenter
vmovq xmm0, [.value+$08]
fleave
end if ; </fold>
if(used avt.lang.Short8$create$short4$short4$) ; <fold returns short8>
fast avt.lang.Short8$create$short4$short4$, \
value0, short4, \
value1, short4
fenter
vmovdqa xmm0, [.value0]
vmovdqa xmm1, [.value1]
vpslldq xmm1, xmm1, $08
vpor xmm0, xmm0, xmm1
fleave
end if ; </fold>
if(used avt.lang.Short8$create$short2$short2$short2$short2$) ; <fold returns short8>
fast avt.lang.Short8$create$short2$short2$short2$short2$, \
value0, short2, \
value1, short2, \
value2, short2, \
value3, short2
fenter
vmovdqa xmm0, [.value0]
vmovdqa xmm1, [.value1]
vmovdqa xmm2, [.value2]
vmovdqa xmm3, [.value3]
vpslldq xmm1, xmm1, $04
vpslldq xmm2, xmm2, $08
vpslldq xmm3, xmm3, $0c
vpor xmm0, xmm0, xmm1
vpor xmm0, xmm0, xmm2
vpor xmm0, xmm0, xmm3
fleave
end if ; </fold>
if(used avt.lang.Short8$max$short8$short8$) ; <fold returns short8>
fast avt.lang.Short8$max$short8$short8$, \
value0, short8, \
value1, short8
fenter
vmovdqa xmm0, [.value0]
vpmaxsw xmm0, xmm0, [.value1]
fleave
end if ; </fold>
if(used avt.lang.Short8$maxUnsigned$short8$short8$) ; <fold returns short8>
fast avt.lang.Short8$maxUnsigned$short8$short8$, \
value0, short8, \
value1, short8
fenter
vmovdqa xmm0, [.value0]
vpmaxuw xmm0, xmm0, [.value1]
fleave
end if ; </fold>
if(used avt.lang.Short8$min$short8$short8$) ; <fold returns short8>
fast avt.lang.Short8$min$short8$short8$, \
value0, short8, \
value1, short8
fenter
vmovdqa xmm0, [.value0]
vpminsw xmm0, xmm0, [.value1]
fleave
end if ; </fold>
if(used avt.lang.Short8$minUnsigned$short8$short8$) ; <fold returns short8>
fast avt.lang.Short8$minUnsigned$short8$short8$, \
value0, short8, \
value1, short8
fenter
vmovdqa xmm0, [.value0]
vpminuw xmm0, xmm0, [.value1]
fleave
end if ; </fold>
if(used avt.lang.Short8$rotateLeft$short8$int$) ; <fold returns short8>
fast avt.lang.Short8$rotateLeft$short8$int$, \
value, short8, \
bits, int
fenter
mov r01d, [.bits]
and r01d, $0f
mov r02d, $10
sub r02d, r01d
vmovdqa xmm1, [.value]
vmovd xmm2, r01d
vmovd xmm3, r02d
vpsllw xmm0, xmm1, xmm2
vpsrlw xmm1, xmm1, xmm3
vpor xmm0, xmm0, xmm1
fleave
end if ; </fold>
if(used avt.lang.Short8$rotateRight$short8$int$) ; <fold returns short8>
fast avt.lang.Short8$rotateRight$short8$int$, \
value, short8, \
bits, int
fenter
mov r01d, [.bits]
and r01d, $0f
mov r02d, $10
sub r02d, r01d
vmovdqa xmm1, [.value]
vmovd xmm2, r01d
vmovd xmm3, r02d
vpsrlw xmm0, xmm1, xmm2
vpsllw xmm1, xmm1, xmm3
vpor xmm0, xmm0, xmm1
fleave
end if ; </fold>
if(used avt.lang.Short8$setElement$short8$int$short$) ; <fold returns short8>
fast avt.lang.Short8$setElement$short8$int$short$, \
value, short8, \
index, int, \
element, short
fenter
mov r01d, [.index]
cmp r01d, $08
jb @F
fthrow VectorIndexOutOfBoundsException
@@: mov r00d, [.element]
mov word [.value+r01*2+$00], r00w
vmovdqa xmm0, [.value]
fleave
end if ; </fold>
if(used avt.lang.Short8$toInt4Bits$short8$) ; <fold returns int4>
fast avt.lang.Short8$toInt4Bits$short8$, \
value, short8
fenter
vmovdqa xmm0, [.value]
fleave
end if ; </fold>
if(used avt.lang.Short8$toLong2Bits$short8$) ; <fold returns long2>
fast avt.lang.Short8$toLong2Bits$short8$, \
value, short8
fenter
vmovdqa xmm0, [.value]
fleave
end if ; </fold>
; </fold>
