;
; Реализация среды исполнения языка программирования
; Объектно-ориентированный продвинутый векторный транслятор
;
; Copyright © 2021, 2024 Малик Разработчик
;
; Это свободная программа: вы можете перераспространять ее и/или изменять
; ее на условиях Меньшей Стандартной общественной лицензии GNU в том виде,
; в каком она была опубликована Фондом свободного программного обеспечения;
; либо версии 3 лицензии, либо (по вашему выбору) любой более поздней версии.
;
; Эта программа распространяется в надежде, что она будет полезной,
; но БЕЗО ВСЯКИХ ГАРАНТИЙ; даже без неявной гарантии ТОВАРНОГО ВИДА
; или ПРИГОДНОСТИ ДЛЯ ОПРЕДЕЛЕННЫХ ЦЕЛЕЙ. Подробнее см. в Меньшей Стандартной
; общественной лицензии GNU.
;
; Вы должны были получить копию Меньшей Стандартной общественной лицензии GNU
; вместе с этой программой. Если это не так, см.
; <https://www.gnu.org/licenses/>.
;
; <fold векторный беззнаковый сдвиг вправо>
if(used inst$vshrub2) ; <fold returns byte2>
label inst$vshrub2 at inst$vshrub4
end if ; </fold>
if(used inst$vshrub4) ; <fold returns byte4>
proc inst$vshrub4
and dsc0, $1f
vmovd xmm1, dsc0
vpsrld xmm0, xmm0, xmm1
vpand xmm0, xmm0, [cons$int8.maskb]
vpxor xmm1, xmm0, xmm0
vpackusdw xmm0, xmm0, xmm1
vpackuswb xmm0, xmm0, xmm1
ret
end_proc
end if ; </fold>
if(used inst$vshrub8) ; <fold returns byte8>
proc inst$vshrub8
and dsc0, $1f
vmovd xmm1, dsc0
vpsrld ymm0, ymm0, xmm1
vpand ymm0, ymm0, [cons$int8.maskb]
vextracti128 xmm1, ymm0, $01
vpxor xmm2, xmm0, xmm0
vpackusdw xmm0, xmm0, xmm1
vpackuswb xmm0, xmm0, xmm2
ret
end_proc
end if ; </fold>
if(used inst$vshrus2) ; <fold returns short2>
label inst$vshrus2 at inst$vshrus4
end if ; </fold>
if(used inst$vshrus4) ; <fold returns short4>
proc inst$vshrus4
and dsc0, $1f
vmovd xmm1, dsc0
vpsrld xmm0, xmm0, xmm1
vpand xmm0, xmm0, [cons$int8.maskw]
vpxor xmm1, xmm0, xmm0
vpackusdw xmm0, xmm0, xmm1
ret
end_proc
end if ; </fold>
if(used inst$vshrus8) ; <fold returns short8>
proc inst$vshrus8
and dsc0, $1f
vmovd xmm1, dsc0
vpsrld ymm0, ymm0, xmm1
vpand ymm0, ymm0, [cons$int8.maskw]
vextracti128 xmm1, ymm0, $01
vpackusdw xmm0, xmm0, xmm1
ret
end_proc
end if ; </fold>
; </fold>
